* Encoding: UTF-8.
*PSYb2520 Seminář 2 - Lineární regrese.

*Data jsou z Long2 data_zakladni.sav.

*Modelovat budeme depresivitu.
*deprese je  Sumační škála (n01 .. n20). r=0,88

FREQ N01_99 TO N20_99.
DESC  N01_99 TO N20_99.
CORR N01_99 TO N20_99.
*Listwise pouze 680 případů ze 768.
COMPUTE DEP_MISS = NMISS(N01_99 TO N20_99).
EXECUTE.
FREQ DEP_MISS.
*Budu tolerovat 2 chybějící odpovědi z 20.
COMPUTE DEPRESE = MEAN.18(N01_99 TO N20_99).
EXECUTE. 
EXAMINE DEPRESE.

*Prediktory by podle mé ad-hoc teorie měly být: 
*selfe (self-esteem) - nutno vytvořit.  
*duv_v (důvěra k vrstevníkům) - nutno vytvořit.
*vekr (věk) - v datech
*mat99 (známka z matematiky) - v datech.
*zdravi (zdravotní potíže psychosomatického rázu) - nutno vytvořit.

*Selfesteem - sumační škála (k02,k03,k04,k05,k06,k08,k09,k12).
FREQ k02_99 k03_99 k04_99 k05_99 k06_99 k08_99 k09_99 k12_99.
DESC k02_99 k03_99 k04_99 k05_99 k06_99 k08_99 k09_99 k12_99.
CORR k02_99 k03_99 k04_99 k05_99 k06_99 k08_99 k09_99 k12_99.
*Listwise 720.
COMPUTE SE_MISS = NMISS(k02_99, k03_99, k04_99, k05_99, k06_99, k08_99, k09_99, k12_99).
EXECUTE.
FREQ SE_MISS.
*Budu tolerovat 1 chybějící odpověď.
COMPUTE SELFE = MEAN.7(k02_99, k03_99, k04_99, k05_99, k06_99, k08_99, k09_99, k12_99).
EXECUTE. 
EXAMINE SELFE.

*Důvěra k vrstevníkům. sumační škála (d02, d04, d06 .. d12).
FREQ D02_99 D04_99 D06_99 D08_99 D10_99 D12_99.
DESC D02_99 D04_99 D06_99 D08_99 D10_99 D12_99.
CORR D02_99 D04_99 D06_99 D08_99 D10_99 D12_99.
*Listwise 725.
COMPUTE DUV_MISS = NMISS(D02_99, D04_99, D06_99, D08_99, D10_99, D12_99).
EXECUTE.
FREQ DUV_MISS.
*Budu tolerovat 1 chybějící odpověď.
COMPUTE DUVERA = MEAN.5(D02_99, D04_99, D06_99, D08_99, D10_99, D12_99).
EXECUTE. 
EXAMINE DUVERA.

*Zdraví - L01-L15.
FREQ L01_99 TO L15_99.
DESC L01_99 TO L15_99.
CORR L01_99 TO L15_99.
*Jen 705 listwise.
COMPUTE ZDR_MISS = NMISS(L01_99 TO L15_99).
EXECUTE.
FREQ ZDR_MISS.
*Budu tolerovat 2 chybějící hodnoty.
COMPUTE ZDRAVI = MEAN.13(L01_99 TO L15_99).
EXECUTE. 
EXAMINE ZDRAVI.

*Jen pro inlustraci.
DESC N01_99 TO N20_99 k02_99 k03_99 k04_99 k05_99 k06_99 k08_99 k09_99 k12_99 D02_99 D04_99 D06_99 D08_99 D10_99 D12_99 L01_99 TO L15_99.
*Listwise 603.

*******************************************************************************.
*Máme potřebné proměnné, můžeme se pustit do analýzy.

********************************************************************************.
*Popisné statistiky a seznámení s daty.

EXAMINE VARIABLES=DEPRESE SELFE DUVERA ZDRAVI vekr mat99
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING PAIRWISE
  /NOTOTAL.

DESC DEPRESE SELFE DUVERA ZDRAVI vekr mat99.
*Pokud to bude možné, budeme chtít pracovat pairwise.


GRAPH
  /SCATTERPLOT(MATRIX)=DEPRESE SELFE DUVERA ZDRAVI vekr mat99
  /MISSING=LISTWISE.

CORR DEPRESE SELFE DUVERA ZDRAVI vekr mat99.

GRAPH
  /SCATTERPLOT(BIVAR)=SELFE WITH DEPRESE
  /MISSING=LISTWISE.

MVA VARIABLES=DEPRESE SELFE DUVERA ZDRAVI vekr mat99 
  /TPATTERN PERCENT=0.


**********************************************************************************************.
*První spuštění regrese.

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL ZPP
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT DEPRESE
  /METHOD=ENTER SELFE DUVERA ZDRAVI vekr mat99
  /PARTIALPLOT ALL
  /SCATTERPLOT=(*ZRESID ,*ZPRED)
  /RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
  /CASEWISE PLOT(ZRESID) OUTLIERS(3)
  /SAVE PRED COOK LEVER RESID ZRESID SRESID DFBETA DFFIT.



*Alternativní příběh.

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN CHANGE TOL ZPP
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT DEPRESE
  /METHOD=ENTER vekr
  /METHOD=ENTER ZDRAVI  mat99
  /METHOD=ENTER SELFE DUVERA
  /PARTIALPLOT ALL
  /SCATTERPLOT=(*ZRESID ,*ZPRED)
  /RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
  /CASEWISE PLOT(ZRESID) OUTLIERS(3).