* Encoding: UTF-8.

* Skotské zkoušky.
* Seznámení se s multilevel daty.
* Data na individuální úrovni (L1).
* Identifikátorem jednotlivce  je ID.
FREQUENCIES gender.
DESCRIPTIVES test points.
GRAPH
  /HISTOGRAM=test.
GRAPH
  /HISTOGRAM=points.

*Data na druhé úrovni (L2).
* Identifikátor školy je schoolID.
FREQ schoolID nbrhd.



*Obyčejná regrese.
*Nerozlišuje z jaké úrovně pochází data.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT test
  /METHOD=ENTER points gender nbrhd.

*Jak moc záleží na tom, z jaké školy dítě pochází?.
*Rozložení průměrů napříč školami.
GGRAPH 
  /GRAPHDATASET NAME="graphdataset" VARIABLES=SchoolID[LEVEL=NOMINAL] test MISSING=LISTWISE 
    REPORTMISSING=NO 
  /GRAPHSPEC SOURCE=INLINE. 
BEGIN GPL 
  SOURCE: s=userSource(id("graphdataset")) 
  DATA: SchoolID=col(source(s), name("SchoolID"), unit.category()) 
  DATA: test=col(source(s), name("test")) 
  DATA: id=col(source(s), name("$CASENUM"), unit.category()) 
  GUIDE: axis(dim(1), label("Škola")) 
  GUIDE: axis(dim(2), label("Body z testu")) 
  GUIDE: text.title(label("Simple Boxplot of Body z testu by Škola")) 
  SCALE: linear(dim(2), include(0)) 
  ELEMENT: schema(position(bin.quantile.letter(SchoolID*test)), label(id)) 
END GPL.

*... další grafy naklikat.



*Jak moc rozptylu závislé vysvětluje škola?.
*Unconditional means model.
MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(SchoolID) SOLUTION.

*Postupně začneme budovat multilevel model přidáváním náhodných efektů.
*Random intercept model.
*Zatím pouze s proměnnými na úrovni jednotlivce.

MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT gender points | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(SchoolID).

*Jen pro porovnání - gender jako explicitně kategorická.
MIXED test WITH points nbrhd BY gender
  /FIXED=INTERCEPT gender points | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(SchoolID).

*A přidáme proměnnou na úrovni školy.
MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT gender points nbrhd | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(SchoolID).

* Přidáme interakci mezi sousedství a genderem - cross-level interaction.
MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT gender points nbrhd gender*nbrhd | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(SchoolID).

*Přidáme náhodný efekt genderu a  bodů (napříč školami).
*(interakci zahazujeme).
MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT gender points nbrhd  | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV
  /RANDOM=INTERCEPT gender points | SUBJECT(SchoolID) COVTYPE(VC).

*Umožníme náhodným efektům, aby spolu korelovaly.
MIXED test WITH gender points nbrhd
  /FIXED=INTERCEPT gender points nbrhd  | SSTYPE(3)
  /METHOD=REML
  /PRINT=  SOLUTION TESTCOV HISTORY
  /RANDOM=INTERCEPT gender points | SUBJECT(SchoolID) COVTYPE(UN).






*Nová data - PTIsimple.
*Neapomnout uložit data do nového souboru.

VARSTOCASES
   /MAKE PTI FROM PTI_K PTI_NS PTI_KS
  /INDEX=Stroop "Stroop - podmínka" 
  /KEEP=ID sex SAS TSC40 BDI 
  /NULL=DROP.


VALUE LABELS Stroop
1 "Klid"
2 "Nekonfliktní Stroop"
3 "Konfliktní Stroop".


EXAMINE VARIABLES=PTI BY Stroop
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

* Chart Builder.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=Stroop MEAN(PTI)[name="MEAN_PTI"] ID[LEVEL=NOMINAL] 
    MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: Stroop=col(source(s), name("Stroop"), unit.category())
  DATA: MEAN_PTI=col(source(s), name("MEAN_PTI"))
  DATA: ID=col(source(s), name("ID"), unit.category())
  GUIDE: axis(dim(1), label("Stroop - podmínka"))
  GUIDE: axis(dim(2), label("Mean PTI klid"))
  GUIDE: legend(aesthetic(aesthetic.color.interior), label("ID"))
  SCALE: cat(dim(1), include("1", "2", "3"))
  SCALE: linear(dim(2), include(0))
  ELEMENT: line(position(Stroop*MEAN_PTI), color.interior(ID), missing.wings())
END GPL.



MIXED PTI BY Stroop
  /FIXED=INTERCEPT Stroop | SSTYPE(3)
  /METHOD=REML
  /PRINT=DESCRIPTIVES LMATRIX SOLUTION TESTCOV
  /RANDOM=INTERCEPT | SUBJECT(ID) COVTYPE(UN)
  /EMMEANS=TABLES(Stroop) COMPARE REFCAT(FIRST) ADJ(SIDAK)
  /TEST "Stroop Helmertovy kontrasty" Stroop 1 -1/2 -1/2; Stroop 0 1 -1.