* Encoding: UTF-8.
*Generování fake dat navíc.
COMPUTE hair=Rnd(RV.UNIFORM(1,3)).
EXECUTE.
Variable labels hair "Hair color".
value labels hair
1 "blond"
2 "brown"
3 "black".

IF (hair= 1) salary_new = salary + 5*hair + (beauty-55)*2 -15. 
IF (hair= 2) salary_new = salary + 3*hair.
IF (hair= 3) salary_new = salary + 4*hair.
IF (salary_new < 0) salary_new = 3.
execute.

*freq hair.
*GRAPH   /HISTOGRAM=salary_new.
*GRAPH   /HISTOGRAM=beauty.

*Uložení dat s přidanými proměnnými.
SAVE OUTFILE='C:\Users\JEZEK\Dropbox\!Výuka\PSY252\Bloky\2 Regrese\Supermodel_new.sav'
  /DROP=salary
  /COMPRESSED.
*Konec vyrábění fake dat.
*_______________________________________________________________________________________________________.

*Predikujeme mzdu supermodelek.


*Podívejme se na závislou. 
EXAMINE VARIABLES=salary_new
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*Je hodně zešikmená. Navíc, zákon marginálního užitku naznačuje, že u vysokých mezd je potřeba přidat víc, aby to bylo vidět, než u nízkých.
compute salary_log = ln(salary_new-2).
execute.

EXAMINE VARIABLES=salary_new salary_log
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*Budeme modelovat raději tu transfomovanou proměnnou.
*Jsou tam dva outlieři. Nebudu je vyřazovat, ale už si na ně mohu nachystat filtr pro "analýzu senzitivity".
USE ALL.
COMPUTE filter_$=(salary_log>1).
VARIABLE LABELS filter_$ 'salary_log>1 (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMATS filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.


*Prediktory.
*Nejprve spojité.
DESC salary_log age years beauty.
CORR salary_log age years beauty.
GRAPH
  /SCATTERPLOT(MATRIX)=salary_log age years beauty
  /MISSING=LISTWISE.
GRAPH
  /SCATTERPLOT(BIVAR)=age WITH salary_log
  /MISSING=LISTWISE.
GRAPH
  /SCATTERPLOT(BIVAR)=years WITH salary_log
  /MISSING=LISTWISE.
GRAPH
  /SCATTERPLOT(BIVAR)=age WITH years
  /MISSING=LISTWISE.

*Kategorický.
FREQ hair.
EXAMINE VARIABLES=salary_log salary_new BY hair
  /PLOT BOXPLOT HISTOGRAM
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

*Transformace Hair do dummy proměnných.
recode hair (1=1) (2=0) (3=0) into hair_blond.
recode hair (1=0) (2=1) (3=0) into hair_brown.
execute.

*A první dva kroky regrese.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL CHANGE ZPP
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT salary_log
  /METHOD=ENTER years age
  /METHOD=ENTER beauty hair_blond hair_brown
  /PARTIALPLOT ALL.

*Zde bychom mohli řešit interpretaci věku a doby strávené modelingem.


*Moderace
*Spočítáme si moderační/interakřní členy.
compute blondXbeauty =  hair_blond * beauty.
compute brownXbeauty =  hair_brown * beauty.
execute.

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL CHANGE
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT salary_log
  /METHOD=ENTER years age
  /METHOD=ENTER hair_blond hair_brown beauty 
  /METHOD=ENTER blondXbeauty brownXbeauty
  /PARTIALPLOT ALL.

*Brutální kolinearita - je potřeba krásu vycentrovat.
desc beauty.
compute beautyC = beauty - 75.944705.
execute.
*A taky spočítat nové interakční členy.
compute blondXbeautyC =  hair_blond * beautyC.
compute brownXbeautyC =  hair_brown * beautyC.
execute.


REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL CHANGE
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT salary_log
  /METHOD=ENTER years age
  /METHOD=ENTER hair_blond hair_brown beautyC 
  /METHOD=ENTER blondXbeautyC brownXbeautyC
  /PARTIALPLOT ALL.





*Diagnostický běh na finálním modelu.
REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA COLLIN TOL CHANGE
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT salary_log
  /METHOD=ENTER age years hair_blond hair_brown beautyC blondXbeautyC brownXbeautyC
  /PARTIALPLOT ALL
  /SCATTERPLOT=(*ZRESID ,*ZPRED)
  /RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
  /CASEWISE PLOT(ZRESID) OUTLIERS(3)
  /SAVE COOK LEVER.