* Encoding: UTF-8.

*Převedení "Sex" ze string na numerickou proměnnou.
AUTORECODE VARIABLES=Sex 
  /INTO sex_num
  /DESCENDING
  /PRINT.

* Vytvoření dummy proměnných pro oslovení (title) pasažéra, pokud se daný titul vyskuteje v proměnné "Name".
COMPUTE title_Master = (INDEX(Name,'Master') > 0).
COMPUTE title_Mrs = (INDEX(Name,'Mrs.') > 0).
COMPUTE title_Miss = (INDEX(Name,'Miss.') > 0).
EXECUTE.

* Nové dummy proměnné.indikující třídu (referenční kategorií je 3. třída), 
počet spolucestujících sourozenců/chotí (referenční kategorií jsou žádní),
počet spolucestujících rodičů/dětí (referenční kategorií jsou žádní). 
RECODE Pclass (1=Copy) (MISSING=SYSMIS) (ELSE=0) INTO class_1.
RECODE Pclass (2=Copy) (MISSING=SYSMIS) (ELSE=0) INTO class_2.
RECODE SibSp (1=Copy) (0=0) (2 thru Highest=0) INTO SibSp_1.
RECODE SibSp (1=0) (0=0) (2 thru Highest=1) INTO SibSp_2plus.
RECODE Parch (1=Copy) (0=0) (2 thru Highest=0) INTO Parch_1.
RECODE Parch (1=0) (0=0) (2 thru Highest=1) INTO Parch_2plus.
EXECUTE.

* Predikce věku na zákaldě pohlaví, třídy, titulu a počtu spolucestujících sorozenců/chotí a počtu rodičů/dětí +
 uložení predikovaných hodnot příkazem SAVE do proměnné age_predicted.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Age
  /METHOD=ENTER sex_num title_Master title_Mrs title_Miss class_1 class_2 SibSp_1 SibSp_2plus 
    Parch_1 Parch_2plus
  /SAVE PRED(age_predicted).

* vytvoření proměnné age_imputed s imputací predikovaného věku, chybí-li původní hodnota věku (jinak zkopírovat původní hodnotu).
DO IF MISSING(Age).
    COMPUTE age_imputed = age_predicted.
ELSE.
     COMPUTE age_imputed = Age.
END IF.
EXECUTE.