* Encoding: UTF-8.
*############################################################
          OVĚŘENÍ PŘEDPOKLADŮ DVOUÚROVŇOVÉ REGRESE
*############################################################
* REZIDUA ÚROVNĚ 1 BY MĚLA MÍT PŘIBLIŽNĚ NORMÁLNÍ ROZDĚLENÍ.
    * Jak je vidět, jsou trochu pravostranně zešikmenná, ale je to celkem OK.
EXAMINE VARIABLES=ml_resid
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
    

* REZIDUA ÚROVNĚ 1 BY MĚLA BÝT VZÁJEMNĚ NEZÁVISLÁ.
     *Ne u všech respondentů vypadá ten shluk bodů náhodně, některá rezidua jsou tedy vzájemně závislá 
     *To je dáno tím, že ne u všech respondentů byl vztah mezi číslem měření a úrovní úzkosti lineární..
SPLIT FILE LAYERED BY id.
GRAPH
  /SCATTERPLOT(BIVAR) = diary WITH ml_resid
  /MISSING=LISTWISE.
SPLIT FILE OFF.


* REZIDUA ÚROVNĚ 1 BY NEMĚLA ZÁVISET NA HODNOTÁCH PREDIKTORŮ ÚROVNĚ 1. 
    * Tento předpoklad je.dle všeho dodržen, protože to nevypadá, že by hodnoty reziduí souvisely s hodnotami prediktorů úrovně 1.
EXAMINE VARIABLES=ml_resid BY solo
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES=ml_resid BY bigger
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES=ml_resid BY diary
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

GRAPH
  /LINE(SIMPLE)=MEAN(id) BY diary
  /INTERVAL CI(95.0).

* ROZPTYL REZIDUÍ ÚROVNĚ 1 BY MĚL BÝT V RÁMCI KAŽDÉ "JEDNOTKY"  PŘIBLIŽNĚ STEJNÝ.
    * Obtížné posoudit kvůli poměrně malému počtu pozorování v rámci jednoho hudebníka (max 15).
    * Ale vzhledem k nedodržení linearity lze očekávat větší rozptyl reziduí právě u těch hudebníků, kde vztah mezi číslem měření a trémou nebyl lineární.
    * Také vidíme několik případů s vysokými rezidui (možná vysoká tréma při velmi důležitém vystoupení).
    * ČIli tento předpoklad zřejmě není dodržen.
EXAMINE VARIABLES=ml_resid BY id
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

* RESIDUA ÚROVNĚ 2 BY MĚLA BÝT VZÁJEMNĚ NEZÁVISLÁ.
    *Obtížně posouditelné vzhledem k tomu, že nemáme proměnnou, podle které bychom respondenty smysluplně (nikoli arbitrárně) seřadili.
    *Kdybychom ale měli takovou proměnnou (třeba informace o škole, do které respondenti chodí), mohli bychom se podívat zda úroveň reziduí 2 úrovně liší v závislosti na ní.
    *Zde jen na ukázka toho, když respondenty seřadíme podle arbitrárního ID.
FILTER BY first_measurement.
GRAPH 
  /SCATTERPLOT(BIVAR) = id WITH r_intercept
  /MISSING=LISTWISE.

GRAPH
  /SCATTERPLOT(BIVAR) = id WITH r_diary
  /MISSING=LISTWISE.
FILTER OFF.

* REZIDUA 2 ÚROVNĚ BY MĚLA VYKAZOVAT MULTIVARIAČNÍ NORMALITU.
* Rezidua 2 úrovně jsou vlastně odhady náhodných průsečiků a náhodné směrnice pro čas měření pro jednotlivé respondenty 
* protože se jedná o odchylky od fixního průsečíku a fixní směrnice..
    *Obvykle se spokojíme s ověřením univariační normality.
FILTER BY first_measurement.
EXAMINE VARIABLES=r_intercept r_diary
  /PLOT BOXPLOT HISTOGRAM
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
    
* Další možností je uložení mahalanobisovvých vzdálenosti.
* které jsou měřítkem vzálenosti pozorování od středu multivariační distribuce.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT mean_na
  /METHOD=ENTER r_intercept r_diary
  /SAVE MAHAL(mahal_dist).

* A pak se podíváme, které případy z hlediska Mahalanobisových vzdáleností "odskakují" od zbytku distribuce.
EXAMINE VARIABLES= mahal_dist
  /PLOT BOXPLOT STEMLEAF HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.
    *Jsou to případy začínající na řádcích 455 a 178 (oba velmi nizký náhodný průsečík a vysokokou náhodnou směrnici) a případ 344 (ten má velmi nízký náhodný průsečík).
FILTER OFF.


*REZIDUA ÚROVNĚ 2 BY MĚLA BÝT NEZÁVISLÁ NA HODNOTÁCH PREDIKTORŮ ÚROVNĚ 2. 
      * Zdá se, že tam žádný vztah není, ale ty tři extrémní případy mohou indikovat to,
      že u osob s vyšší negativní emocionalitou dochází k vyššímu výkyvu nálady,
      a proto jejich náhodné průsečíky, související s uvedenou trému při prvním měření, více kolísají.

FILTER BY first_measurement.

GRAPH
  /SCATTERPLOT(BIVAR)=mpqnem_cen32 WITH r_intercept
  /MISSING=LISTWISE.

GRAPH
  /SCATTERPLOT(BIVAR)=mpqnem_cen32 WITH r_diary
  /MISSING=LISTWISE.

FILTER OFF.

* REZIDUA ÚROVNĚ 1 BY NEMĚLA SOUVISET S REZIDUI ÚROVNĚ 2.
    * Žádný výrazný trend zde není.
    * Tento předpokald se zdá být dodržen.
GRAPH
  /SCATTERPLOT(BIVAR)= r_intercept WITH ml_resid
  /MISSING=LISTWISE.

GRAPH
  /SCATTERPLOT(BIVAR)= r_diary WITH ml_resid
  /MISSING=LISTWISE.

* PREDIKTORY ÚROVNĚ 1 BY MĚLY BÝT NEZÁVISLÉ NA REZIDUÍCH ÚROVNĚ 2 .
    *Tento předpoklad se zdá být dodržen.
EXAMINE VARIABLES = r_intercept BY solo
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES = r_diary BY solo
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES = r_intercept BY bigger
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES = r_diary BY bigger
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES = r_intercept BY diary
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

EXAMINE VARIABLES = r_diary BY diary
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL.

*A NAOPAK PREDIKTORY ÚROVNĚ 2 BY MĚLY BÝT NEZÁVISLÉ NA REZIDUÍCH ÚROVNĚ 1. 
 * Tento předpoklad se zdá být dodržen.
GRAPH
  /SCATTERPLOT(BIVAR) = mpqnem WITH ml_resid
  /MISSING=LISTWISE.