* Encoding: UTF-8.

*************************************** Manuál pro SPSS ***************************************.

* načtení souboru Data_neuro_original pro kapitolu 1 a 2.
GET DATA
  /TYPE=XLSX
  /FILE='c:\Users\koritakova\Documents\Vyuka\DSAN01\2017 jaro\Manuál_SPSS\data_neuro_original.xlsx'
  /SHEET=name 'data'
  /CELLRANGE=FULL
  /READNAMES=ON
  /DATATYPEMIN PERCENTAGE=95.0
  /HIDDEN IGNORE=YES.
EXECUTE.

* uložení datového souboru.
SAVE OUTFILE='c:\Users\koritakova\Documents\Vyuka\DSAN01\2017 jaro\Manuál_SPSS\Data_neuro_original.sav'
  /COMPRESSED.



*********** 1. Vizualizace dat - pomocí záložky Graphs ***********.

* Koláčový graf.
GRAPH
  /PIE=COUNT BY Gender.

* Sloupcový graf (na ose y počty lidí).
GRAPH
  /BAR(SIMPLE)=COUNT BY Group.

* Sloupcový graf (na ose y procenta).
GRAPH
  /BAR(SIMPLE)=PCT BY Group.

* Histogram.
GRAPH
  /HISTOGRAM=Age.

* Histogram pomocí Chart Builder - na ose y procenta.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=Age MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: Age=col(source(s), name("Age"))
  GUIDE: axis(dim(1), label("Age"))
  GUIDE: axis(dim(2), label("Frequency Percent"))
  ELEMENT: interval(position(summary.percent.count(bin.rect(Age), base.all(acrossPanels()))), 
    shape.interior(shape.square))
END GPL.

* Krabicový graf (s vykreslením odlehlých hodnot).
EXAMINE VARIABLES=Age 
  /COMPARE VARIABLE
  /PLOT=BOXPLOT
  /STATISTICS=NONE
  /NOTOTAL
  /MISSING=LISTWISE.


*********** 2. Příprava dat pro analýzu ***********.

* Nastavení formátu u MMSE na Typ=Numeric (s 0 desetinnými místy) a Measure=Scale.
ALTER TYPE  MMSE(F2.0).
VARIABLE LEVEL  MMSE(SCALE).

* Nastaveni formátu u scan_date na datum (různé možnosti formátu datum).
ALTER TYPE  scan_date(EDATE10).
ALTER TYPE  scan_date(DATE11).
ALTER TYPE  scan_date(SDATE10).

* Úprava počtu desetinných míst.
FORMATS  Weight(F4.1).

* Identifikace duplikací - jako duplikát se označí nejstarší datum.
SORT CASES BY ID(A) scan_date(A).
MATCH FILES
  /FILE=*
  /BY ID
  /FIRST=PrimaryFirst
  /LAST=PrimaryLast.
DO IF (PrimaryFirst).
COMPUTE  MatchSequence=1-PrimaryLast.
ELSE.
COMPUTE  MatchSequence=MatchSequence+1.
END IF.
LEAVE  MatchSequence.
FORMATS  MatchSequence (f7).
COMPUTE  InDupGrp=MatchSequence>0.
SORT CASES InDupGrp(D).
MATCH FILES
  /FILE=*
  /DROP=PrimaryFirst InDupGrp MatchSequence.
VARIABLE LABELS  PrimaryLast 'Indicator of each last matching case as Primary'.
VALUE LABELS  PrimaryLast 0 'Duplicate Case' 1 'Primary Case'.
VARIABLE LEVEL  PrimaryLast (ORDINAL).
FREQUENCIES VARIABLES=PrimaryLast.
EXECUTE.

* Identifikace duplikací - jako duplikát se označí nejmladší datum.
SORT CASES BY ID(A) scan_date(A).
MATCH FILES
  /FILE=*
  /BY ID
  /FIRST=PrimaryFirst
  /LAST=PrimaryLast1.
DO IF (PrimaryFirst).
COMPUTE  MatchSequence=1-PrimaryLast1.
ELSE.
COMPUTE  MatchSequence=MatchSequence+1.
END IF.
LEAVE  MatchSequence.
FORMATS  MatchSequence (f7).
COMPUTE  InDupGrp=MatchSequence>0.
SORT CASES InDupGrp(D).
MATCH FILES
  /FILE=*
  /DROP=PrimaryLast1 InDupGrp MatchSequence.
VARIABLE LABELS  PrimaryFirst 'Indicator of each first matching case as Primary'.
VALUE LABELS  PrimaryFirst 0 'Duplicate Case' 1 'Primary Case'.
VARIABLE LEVEL  PrimaryFirst (ORDINAL).
FREQUENCIES VARIABLES=PrimaryFirst.
EXECUTE.

* Odstranění duplikací.
FILTER OFF.
USE ALL.
SELECT IF  (NOT(PrimaryFirst=0)).
EXECUTE.

* Odstranění chybějících a chybných hodnot.
FILTER OFF.
USE ALL.
SELECT IF (MISSING(Age)=0 & Age <= 110 & MISSING(Weight)=0).
EXECUTE.

* Rekódování proměnné Gender, aby obsahovala pouze hodnoty F a M -> do jiné proměnné. 
*(nejprve je nutno pomocí funkce STRING vytvořit novou proměnnou).
STRING Gender_rek (A8).
RECODE Gender ('FF'='F') (ELSE=Copy) INTO Gender_rek.
EXECUTE.

* Rekódování proměnné Gender, aby obsahovala pouze hodnoty F a M -> do stejné proměnné.
RECODE Gender ('FF'='F').
EXECUTE.

* Rekódování proměnné Group, aby obsahovala pouze hodnoty 1 (CN), 2 (MCI), 3 (AD).
RECODE Group (4=3) (3=2) (ELSE=Copy) INTO Group_3kat.
EXECUTE.

* Vytvoření textových popisků u kvalitativní proměnné.
val lab Group_3kat
1 'CN'
2 'MCI'
3 'AD'.



*********** 3. Popisná sumarizace dat ***********.

* Načtení datového souboru Data_neuro pro 3. a další kapitoly.
GET DATA
  /TYPE=XLSX
  /FILE='c:\Users\koritakova\Documents\Vyuka\DSAN01\2017 jaro\Manuál_SPSS\Data_neuro.xlsx'
  /SHEET=name 'data'
  /CELLRANGE=FULL
  /READNAMES=ON
  /DATATYPEMIN PERCENTAGE=95.0
  /HIDDEN IGNORE=YES.
EXECUTE.

* Popisná sumarizace kvalitativních data - frekvenční tabulka.
FREQUENCIES VARIABLES=Group
  /ORDER=ANALYSIS.

* Popisná sumarizace kvalitativních data - frekvenční tabulka - zkrácená forma.
fre Group.

* Popisná sumarizace kvantitativních dat.
DESCRIPTIVES VARIABLES=Age
  /STATISTICS=MEAN STDDEV MIN MAX.

* Popisná sumarizace kvantitativních dat včetně mediánu (pomocí custom tables).
CTABLES
  /VLABELS VARIABLES=Age DISPLAY=LABEL
  /TABLE Age [VALIDN F40.0, MEAN, STDDEV, MEDIAN, MINIMUM, MAXIMUM]
  /CRITERIA CILEVEL=95.

* Popisná sumarizace kvantitativních dat včetně mediánu (pomocí examine).
EXAMINE VARIABLES=Age
  /PLOT NONE
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

* Popisná sumarizace kvantitativních dat - zapnutí filtru (vyfiltrování posledních 20 pacientů).
FILTER OFF.
USE 813 thru 833.
EXECUTE.
DESCRIPTIVES VARIABLES=Age
  /STATISTICS=MEAN STDDEV MIN MAX.

* Vypnutí filtru.
FILTER OFF.
USE ALL.
EXECUTE.

* Jednodušší způsob vyfiltrování pro danou analýzu.
TEMPORARY.
SELECT IF ID>=913 and ID <=933.
DESCRIPTIVES VARIABLES=Age
  /STATISTICS=MEAN STDDEV MIN MAX.

* Jednodušší způsob vyfiltrování pro danou analýzu - zkrácená forma.
temp.
sel if ID>=913 and ID <=933.
DESCRIPTIVES VARIABLES=Age
  /STATISTICS=MEAN STDDEV MIN MAX.


*********** 4. Transformace dat ***********.

* Logaritmická transformace.
COMPUTE Weight_log=LN(Weight).
EXECUTE.

* Standardizace dat.
DESCRIPTIVES VARIABLES=Age
  /SAVE
  /STATISTICS=MEAN STDDEV MIN MAX.

* Centrování dat.
COMPUTE Height_centr=Height-175.97.
EXECUTE.

* Kategorizace.
RECODE  Age (MISSING=COPY) (80 THRU HI=4) (70 THRU HI=3) (60 THRU HI=2) (LO THRU HI=1) 
    (ELSE=SYSMIS) INTO Age_kat.
VARIABLE LABELS  Age_kat 'Age (Binned)'.
FORMATS  Age_kat (F5.0).
VALUE LABELS  Age_kat 1 '< 60' 2 '60 - 69' 3 '70 - 79' 4 '80+'.
VARIABLE LEVEL  Age_kat (ORDINAL).
EXECUTE.


*********** 5. Intervaly spolehlivosti ***********.

* Výpočet střední chyby průměru (standard error) - zde ale není interval spolehlivosti.
DESCRIPTIVES VARIABLES=Age
  /STATISTICS=MEAN STDDEV MIN MAX SEMEAN.

* Výpočet intervalu spolehlivosti - zde však není standardní chyba.
EXAMINE VARIABLES=Age
  /PLOT BOXPLOT STEMLEAF
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

* Interval spolehlivosti i střední chyba průměru (standard error).
CTABLES
  /VLABELS VARIABLES=Age DISPLAY=LABEL
  /TABLE Age [MEAN, MEAN.LCL, MEAN.UCL, SEMEAN]
  /CRITERIA CILEVEL=95.



*********** 6. Statistické testy pro kvantitativní data - parametrické testy ***********.

*jednovýběrový t-test.
T-TEST
  /TESTVAL=6575
  /MISSING=ANALYSIS
  /VARIABLES=Hippocampus_volumemm3
  /CRITERIA=CI(.95).

* párový t-test.
T-TEST PAIRS=Hippocampus_volumemm3 WITH Hippocampus_volume_24mm3 (PAIRED)
  /CRITERIA=CI(.9500)
  /MISSING=ANALYSIS.

* dvouvýběrový t-test.
T-TEST GROUPS=Gender_rek('F' 'M')
  /MISSING=ANALYSIS
  /VARIABLES=Putamen_volumemm3
  /CRITERIA=CI(.95).

* ANOVA a post-hoc testy.
ONEWAY Hippocampus_volumemm3 BY Group_3kat
  /STATISTICS HOMOGENEITY BROWNFORSYTHE 
  /MISSING ANALYSIS
  /POSTHOC=TUKEY SCHEFFE ALPHA(0.05).



*********** 7. Statistické testy pro kvantitativní data - neparametrické testy ***********.

* Wilcoxonův test - jednovýběrový.
NPTESTS 
  /ONESAMPLE TEST (MMSE) WILCOXON(TESTVALUE=27.5) 
  /MISSING SCOPE=ANALYSIS USERMISSING=EXCLUDE
  /CRITERIA ALPHA=0.05 CILEVEL=95.


* Wilcoxonův párový test.
*1. způsob.
NPTESTS 
  /RELATED TEST(MMSE MMSE_24) WILCOXON 
  /MISSING SCOPE=ANALYSIS USERMISSING=EXCLUDE
  /CRITERIA ALPHA=0.05  CILEVEL=95.

*2. způsob.
NPAR TESTS
  /WILCOXON=MMSE WITH MMSE_24 (PAIRED)
  /MISSING ANALYSIS.


* Mannův-Whitneyův test.
*1. způsob.
NPTESTS 
  /INDEPENDENT TEST (Hippocampus_volumemm3) GROUP (Gender_rek) MANN_WHITNEY 
  /MISSING SCOPE=ANALYSIS USERMISSING=EXCLUDE
  /CRITERIA ALPHA=0.05  CILEVEL=95.

*2. způsob.
* nejprve je třeba rekódvat proměnnou Gender_rek na numerickou.
AUTORECODE VARIABLES=Gender_rek 
  /INTO Gender_rek2
  /BLANK=MISSING
  /PRINT.

NPAR TESTS
  /M-W= Hippocampus_volumemm3 BY Gender_rek2(1 2)
  /MISSING ANALYSIS.


* Kruskalův-Wallisův test.
* 1. způsob.
NPTESTS 
  /INDEPENDENT TEST (Hippocampus_volumemm3) GROUP (Group_3kat) KRUSKAL_WALLIS(COMPARE=PAIRWISE) 
  /MISSING SCOPE=ANALYSIS USERMISSING=EXCLUDE
  /CRITERIA ALPHA=0.05  CILEVEL=95.

*2. způsob.
NPAR TESTS
  /K-W=Hippocampus_volumemm3 BY Group_3kat(1 3)
  /MISSING ANALYSIS.



*********** 8. Ověření předpokladů statistických testů ***********.

* vykreslení Q-Q grafu (nelze však pro jednotlivé skupiny).
PPLOT
  /VARIABLES=Hippocampus_volumemm3
  /NOLOG
  /NOSTANDARDIZE
  /TYPE=Q-Q
  /FRACTION=BLOM
  /TIES=MEAN
  /DIST=NORMAL.

* vykreslení Q-Q grafu pro jednotlivé skupiny + testy normality.
EXAMINE VARIABLES=Hippocampus_volumemm3 BY Gender_rek
  /PLOT BOXPLOT NPPLOT
  /COMPARE GROUPS
  /STATISTICS NONE
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

* vykreslení Q-Q grafu pro jednotlivé skupiny + testy normality + vykreslení histogramů.
EXAMINE VARIABLES=Hippocampus_volumemm3 BY Gender_rek
  /PLOT BOXPLOT HISTOGRAM NPPLOT
  /COMPARE GROUPS
  /STATISTICS NONE
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.



*********** 9. Další užitečné příkazy ***********.

* Popisná sumarizace kvantitativní proměnné podle kategorií kvalitativní proměnné (statistiky ve sloupečcích).
CTABLES
  /VLABELS VARIABLES=Gender_rek Hippocampus_volumemm3 DISPLAY=LABEL
  /TABLE Gender_rek [C] BY Hippocampus_volumemm3 [S][VALIDN F40.0, MEAN, STDDEV, MEDIAN, MINIMUM, MAXIMUM]
  /CATEGORIES VARIABLES=Gender_rek ORDER=A KEY=VALUE EMPTY=EXCLUDE TOTAL=YES POSITION=AFTER
  /CRITERIA CILEVEL=95.

* Popisná sumarizace kvantitativní proměnné podle kategorií kvalitativní proměnné (statistiky v řádcích).
CTABLES
  /VLABELS VARIABLES=Hippocampus_volumemm3 Gender_rek DISPLAY=LABEL
  /TABLE Hippocampus_volumemm3 [S][VALIDN F40.0, MEAN, STDDEV, MEDIAN, MINIMUM, MAXIMUM] BY 
    Gender_rek [C]
  /SLABELS POSITION=ROW
  /CATEGORIES VARIABLES=Gender_rek ORDER=A KEY=VALUE EMPTY=EXCLUDE TOTAL=YES POSITION=AFTER
  /CRITERIA CILEVEL=95.

* Úprava grafu podle šablony.
set ctemplate'C:\Program Files\IBM\SPSS\Statistics\24\Looks\APA_Styles.sgt'.
show ctemplate.
GRAPH
  /BAR(GROUPED)=COUNT BY Group_3kat BY Gender_rek.
set ctemplate none.

* Rozdělení souboru pomocí SPLIT FILE (nejdříve se soubor seřadí pomocí SORT CASES).
SORT CASES  BY ECOG1. 
SPLIT FILE SEPARATE BY ECOG1.

* Zrušení rozdělení souboru pomocí SPLIT FILE.
SPLIT FILE OFF.



*********** 10. Kontingenční tabulky ***********.

** Pomocné výpočty pro získání potřebných proměnných.

* Kategorizace věku.
RECODE Age (Lowest thru 59=1) (59 thru 69=2) (69 thru 79=3) (79 thru Highest=4) INTO Age_kat.
EXECUTE.
VALUE LABELS Age_kat
1 "<60"
2 "60-70"
3 "70-80"
4 ">80".

* Kategorizace věku - 2. způsob.
RECODE  Age (MISSING=COPY) (80 THRU HI=4) (70 THRU HI=3) (60 THRU HI=2) (LO THRU HI=1) 
    (ELSE=SYSMIS) INTO Age_kat.
VARIABLE LABELS  Age_kat 'Age (Binned)'.
FORMATS  Age_kat (F5.0).
VALUE LABELS  Age_kat 1 '< 60' 2 '60 - 69' 3 '70 - 79' 4 '80+'.
VARIABLE LEVEL  Age_kat (ORDINAL).
EXECUTE.

* Kategorizace MMSE_24.
RECODE MMSE_24 (Lowest thru 24=1) (24 thru Highest=0) INTO mmse_24_kat.
EXECUTE.

* Přidání popisku ke kategorizovanému MMSE_24.
VALUE LABELS mmse_kat mmse_24_kat
0 "v norme"
1 "mimo normu".

* Přidání popisku k proměnné Group_3kat.
VALUE LABELS Group_3kat
1 "CN"
2 "MCI"
3 "AD".

* Vytvoření proměnné Gender_rek2, kde hodnota "F" bude nahrazena za "Z".
STRING Gender_rek2 (A8).
RECODE Gender_rek ('F'='Z') (ELSE=Copy) INTO Gender_rek2.
EXECUTE.

* Úprava kategorizovaného MMSE skóre, kdy hodnota 0 je nahrazena za hodnotu 2.
RECODE mmse_kat (0=2) (ELSE=Copy) INTO mmse_kat2.
EXECUTE.
val lab mmse_kat2
1 'mimo normu'
2 'v norme'.


** Analýza kontingenčních tabulek.

* Kontingenční tabulka absolutních četností.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT 
  /COUNT ROUND CELL.

* Kontingenční tabulka procent - řádkových.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT ROW 
  /COUNT ROUND CELL.

* Kontingenční tabulka procent - sloupcových.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT COLUMN 
  /COUNT ROUND CELL.

* Kontingenční tabulka procent - celkových.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT TOTAL 
  /COUNT ROUND CELL.

* Kontingenční tabulka procent - celkových bez absolutních četností (tzn. jenom procenta).
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=TOTAL 
  /COUNT ROUND CELL.

* Kontingenční tabulka očekávaných četností.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /CELLS=EXPECTED 
  /COUNT ROUND CELL.

* Pearsonův chí-kvadrát test.
CROSSTABS
  /TABLES=Group_3kat BY Age_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*Fisherův exaktní test u tabulek větších než 2x2.
CROSSTABS
  /TABLES=Group_3kat BY Gender_rek
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT 
  /COUNT ROUND CELL
  /METHOD=EXACT TIMER(5).

*Fisherův exaktní test u tabulek 2x2 (vypočítá se automaticky).
temp.
sel if Group_3kat=3.
CROSSTABS
  /TABLES=Gender_rek BY mmse_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*McNemarův test.
temp.
sel if Group_3kat=3.
CROSSTABS
  /TABLES=mmse_kat BY mmse_24_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ MCNEMAR 
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*Relativní riziko (RR) a poměr šancí (OR) - pro ženy versus muže.
CROSSTABS
  /TABLES= Gender_rek BY mmse_kat2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

*Relativní riziko (RR) a poměr šancí (OR) - pro muže versus ženy.
CROSSTABS
  /TABLES= Gender_rek2 BY mmse_kat2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

*Relativní riziko (RR) a poměr šancí (OR) včetně p-hodnoty.
LOGISTIC REGRESSION VARIABLES mmse_kat
  /METHOD=ENTER Gender_rek 
  /CONTRAST (Gender_rek)=Indicator
  /PRINT=CI(95)
  /CRITERIA=PIN(0.05) POUT(0.10) ITERATE(20) CUT(0.5).



*** Řešení úkolu 1.

*kategorizace výšky.
RECODE  Height_cor (MISSING=COPY) (180 THRU HI=3) (170 THRU HI=2) (LO THRU HI=1) 
    (ELSE=SYSMIS) INTO Height_cor_kat.
VARIABLE LABELS  Height_cor_kat 'Height categorized'.
FORMATS  Height_cor_kat (F5.0).
VALUE LABELS  Height_cor_kat 1 '< 170 cm' 2 '170 - 180 cm' 3 '180 a vice cm'.
VARIABLE LEVEL  Height_cor_kat (ORDINAL).
EXECUTE.

*tabulka absolutních četností.
CROSSTABS
  /TABLES=Gender_rek BY Height_cor_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*tabulka očekávaných četností.
CROSSTABS
  /TABLES=Gender_rek BY Height_cor_kat
  /FORMAT=AVALUE TABLES
  /CELLS=EXPECTED 
  /COUNT ROUND CELL.

*Pearsonův chí-kvadrát test.
CROSSTABS
  /TABLES=Gender_rek BY Height_cor_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT 
  /COUNT ROUND CELL.


*** Řešení úkolu 2.

temp. 
sel if Gender_rek="M".
CROSSTABS
  /TABLES=group_01_CnMci BY mmse_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT 
  /COUNT ROUND CELL.



*** Pomocný - různé situace při výpočtu RR a OR.

CROSSTABS
  /TABLES= mmse_kat BY Gender_rek
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= mmse_kat BY Gender_rek2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= Gender_rek BY mmse_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= Gender_rek2 BY mmse_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= mmse_kat2 BY Gender_rek
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= mmse_kat2 BY Gender_rek2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= Gender_rek BY mmse_kat2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.

CROSSTABS
  /TABLES= Gender_rek2 BY mmse_kat2
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ RISK 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.



*********** 11. ROC analýza ***********.

* Výpočet ROC křivky, AUC, senzitivity a 1-specificity pro jednotlivé dělící body.
ROC MMSE BY Group_01_CnMci (1)
  /PLOT=CURVE
  /PRINT=SE COORDINATES
  /CRITERIA=CUTOFF(INCLUDE) TESTPOS(SMALL) DISTRIBUTION(FREE) CI(95)
  /MISSING=EXCLUDE.

* Ověření senzitivity a specificity.
RECODE MMSE (Lowest thru 28,5=1) (ELSE=0) INTO mmse_kat2.
EXECUTE.

CROSSTABS
  /TABLES=mmse_kat2 BY group_01_CnMci
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT COLUMN 
  /COUNT ROUND CELL.



*********** 12. Korelační analýza ***********.

* Bodový graf.
GRAPH
  /SCATTERPLOT(BIVAR)=Putamen_volumemm3 WITH Amygdala_volumemm3
  /MISSING=LISTWISE.

* Pearsonův korelační koeficient - 1. způsob.
CORRELATIONS
  /VARIABLES=Amygdala_volumemm3 Putamen_volumemm3
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE.

* Pearsonův korelační koeficient - 2. způsob (spočítá současně i Spearmanův korelační koeficient).
CROSSTABS
  /TABLES=Amygdala_volumemm3 BY Putamen_volumemm3
  /FORMAT=NOTABLES
  /STATISTICS=CORR 
  /COUNT ROUND CELL.

* Spearmanův korelační koeficient.
NONPAR CORR
  /VARIABLES=MMSE Hippocampus_volumemm3
  /PRINT=SPEARMAN TWOTAIL NOSIG
  /MISSING=PAIRWISE.



*********** 13. Regresní analýza ***********.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Nucl_caud_volumemm3
  /METHOD=ENTER Age.

* Q-Q plot a histogram reziduí - 1. způsob.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Nucl_caud_volumemm3
  /METHOD=ENTER Age
  /RESIDUALS HISTOGRAM(ZRESID) NORMPROB(ZRESID).

* Q-Q plot a histogram reziduí - 2. způsob.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Nucl_caud_volumemm3
  /METHOD=ENTER Age
  /SAVE RESID.

EXAMINE VARIABLES=RES_1
  /PLOT BOXPLOT STEMLEAF NPPLOT
  /COMPARE GROUPS
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

* Bodový graf predikovaných hodnot a reziduí.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Nucl_caud_volumemm3
  /METHOD=ENTER Age
  /SCATTERPLOT=(*ZRESID ,*ZPRED).

* Uložení reziduí a predikovaných hodnot.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT Nucl_caud_volumemm3
  /METHOD=ENTER Age
  /SAVE PRED RESID.



*********** 14. Analýza přežití ***********.

* Načtení souboru s přežitím (napr. Data_Cox.xlsx).
GET DATA
  /TYPE=XLSX
  /FILE='c:\Users\koritakova\Documents\Vyuka\DSAN01\2017 jaro\DSAN01_blok7\data_preziti\Data_Cox.xlsx'
  /SHEET=name 'Data_Cox'
  /CELLRANGE=FULL
  /READNAMES=ON
  /DATATYPEMIN PERCENTAGE=95.0
  /HIDDEN IGNORE=YES.
EXECUTE.

* Kaplan-Meier - jeden výběr.
KM OS_doba_mesice
  /STATUS=umrti(1)
  /PRINT TABLE MEAN
  /PLOT SURVIVAL.

* Kaplan-Meier - dva výběry.
KM OS_doba_mesice BY ECOG1
  /STATUS=umrti(1)
  /PRINT TABLE MEAN
  /PLOT SURVIVAL
  /TEST LOGRANK
  /COMPARE OVERALL POOLED.

* Coxův model.
COXREG OS_doba_mesice
  /STATUS=umrti(1)
  /METHOD=ENTER ECOG1 
  /PLOT SURVIVAL
  /PRINT=CI(95)
  /CRITERIA=PIN(.05) POUT(.10) ITERATE(20).
COMMENT BOOKMARK;LINE_NUM=159;NAME=3_popisna_sumarizace;ID=1.
COMMENT BOOKMARK;LINE_NUM=222;NAME=4-5_transformace_a_IS;ID=2.
COMMENT BOOKMARK;LINE_NUM=270;NAME=6-7_parametricke_a_neparametricke_testy;ID=3.
COMMENT BOOKMARK;LINE_NUM=353;NAME=8_overeni_predpokladu;ID=5.
COMMENT BOOKMARK;LINE_NUM=385;NAME=9_dalsi_prikazy;ID=6.
COMMENT BOOKMARK;LINE_NUM=419;NAME=10_kontingencni_tabulky;ID=7.
COMMENT BOOKMARK;LINE_NUM=682;NAME=11_ROC_analyza;ID=8.
COMMENT BOOKMARK;LINE_NUM=703;NAME=12-13_korelace_a_regrese;ID=9.
COMMENT BOOKMARK;LINE_NUM=791;NAME=14_analyza_preziti;ID=4.