* Encoding: UTF-8.

*Načtení dat.
GET DATA 
  /TYPE=XLSX 
  /FILE='C:\Users\koritakova\Documents\Vyuka\DSAN01\2020 jaro\Odpovedniky_IS\Prakticke\neurodata_schizofrenici.xlsx' 
  /SHEET=name 'data' 
  /CELLRANGE=FULL 
  /READNAMES=ON 
  /DATATYPEMIN PERCENTAGE=95.0 
  /HIDDEN IGNORE=YES. 
EXECUTE. 


*** Textové popisky pro kategorie ***.

val lab skupina
1 'Kontroly'
2 'FES'
3 'CH'.

val lab DSS_kat
0 'v normě'
1 'pod normou'.

val lab Stroop_kat
0 'v normě'
1 'pod normou'.

val lab pohlavi
0 'ženy'
1 'muži'.

val lab vzdelani
1 'ZŠ'
2 'SŠ bez maturity'
3 'SŠ s maturitou'
4 'VŠ'.

val lab skupina_FESxK
0 'Kontroly'
1 'FES'.

val lab sebevrazda
0 'ne'
1 'ano'.


*** Otázka 1 ***.
*Zadání: Jaké je procento pacientů s DSS skóre pod normou mezi pacienty s první epizodou schizofrenie a pacienty 
s chronickou schizofrenií?.

CROSSTABS
  /TABLES=skupina BY DSS_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT ROW 
  /COUNT ROUND CELL.

*Závěr: 56,7% pacientů s 1. epizodou schizofrenie a 93,3% pacientů s chronickou schizofrenií má DSS skóre pod normou.



*** Otázka 2 ***.
*Zadání: Existuje statisticky významný vztah mezi pohlavím osob v našem souboru a vzděláním?.

CROSSTABS
  /TABLES=pohlavi BY vzdelani
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.
*Pod tabulkou "Chi-Square Tests" vyčteme, že je 0 buněk s očekávanou četností menší než 5 -> můžeme tedy použít Pearsonův chí-kvadrát test.

*Závěr: Vztah mezi pohlavím a vzděláním není statisticky významný (p=0,454).



*** Otázka 3 ***.
*Zadání: Lze použít Pearsonův chí-kvadrát test k ověření vztahu mezi pohlavím osob v našem souboru a vzděláním?.

*Závěr: Ano, všechny buňky mají očekávanou četnost větší než 5 (viz. text pod tabulkou "Chi-Square Tests" vypočtené u otázky 2).



*** Otázka 4 ***.
*Zadání: Existuje statisticky významný vztah mezi typem onemocnění (proměnná skupina) a kategorizovaným DSS skóre (proměnná DSS_kat)?

CROSSTABS
  /TABLES=skupina BY DSS_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.
*Pod tabulkou "Chi-Square Tests" vyčteme, že je 0 buněk s očekávanou četností menší než 5 -> můžeme tedy použít Pearsonův chí-kvadrát test.

*Závěr: Vztah mezi typem onemocnění a kategorizovaným DSS skóre je statisticky významný (p<0,001).



*** Otázka 5 ***.
*Zadání: Existuje statisticky významný vztah mezi typem onemocnění u pacientů s první epizodou schizofrenie a kontrol (proměnná skupina_FESxK) 
a kategorizovaným Stroopovým skóre (proměnná Stroop_kat)?.

CROSSTABS
  /TABLES=skupina_FESxK BY Stroop_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.
*Čtyřpolní tabulka, proto je nejvhodnější zvolit Fisherův exaktní test. 
*Navíc pod tabulkou "Chi-Square Tests" vyčteme, že je 2 buňky mají očekávanou četnost menší než 5 -> musíme použít Fisherův exaktní test.

*Závěr: Vztah mezi typem onemocnění a kategorizovaným Stroopovým skóre není statisticky významný (p=1,000).



*** Otázka 6 ***.
*Zadání: Zjistěte, zda se liší podíl pacientů s chronickou schizofrenií s DSS skóre pod normou a Stroopovým skóre pod normou:.

temp.
sel if skupina=3.
fre DSS_kat Stroop_kat.
*Procento pacientů pod normou je u DSS skóre i Stroopova skóre 93,3%.
*Jedná se však o párové uspořádání - máme jen jednu skupinu dat s jednou charakteristikou (pod normou x nad normou); tzn. jsou to sice 
2 proměnné, ale vyjadřují obdobnou věc -> použijeme McNemarův test.

temp.
sel if skupina=3.
CROSSTABS
  /TABLES=DSS_kat BY Stroop_kat
  /FORMAT=AVALUE TABLES
  /STATISTICS=MCNEMAR 
  /CELLS=COUNT 
  /COUNT ROUND CELL.

*Závěr: Podíl pacientů s chronickou schizofrenií s DSS skóre pod normou a Stroopovým skóre pod normou se neliší (p=1,000).



*** Otázka 7 ***.
*Zadání: Zjistěte, zda se liší podíl pacientů s první epizodou schizofrenie a kontrol se Stroopovým skóre pod normou:.

CROSSTABS
  /TABLES=skupina_FESxK BY Stroop_kat
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT ROW
  /COUNT ROUND CELL.
*Srovnáváme procenta u různých skupin subjektů -> použijeme dvouvýběrový binomický test.
*Do online kalkulátoru (https://www.medcalc.org/calc/comparison_of_proportions.php) zadáme hodnoty: 96.7; 30; 93.3; 30.

*Závěr: Podíl pacientů s první epizodou schizofrenie a kontrol se Stroopovým skóre pod normou se neliší (p=0,549).



*** Otázka 8 ***.
*Zadání: Zjistěte, zda je podíl pacientů s první epizodou schizofrenie se Stroopovým skóre pod normou statisticky významně 
vyšší než v běžné populaci, kde je podíl lidí pod normou 5%:.

*Z vypočtené tabulky v Otázce 7 vyčteme, že pod normou je 6,7% FES pacientů.
*Srovnáváme procento s referenční hodnotou -> použijeme jednovýběrový binomický test.
*Do online kalkulátoru (https://www.medcalc.org/calc/test_one_proportion.php) zadáme hodnoty: 6.7; 30; 5.
*Dostaneme p=0,669, což je p-hodnota pro oboustranný test. Ptáme se však, zda je podíl VYŠŠÍ než reference, což vede na
jednostranný test. Vzhledem k tomu, že 6,7% je skutečně vyšší než 5%, počítáme p/2 = 0,669/2 = 0,335.

*Závěr: Podíl FES pacientů se Stroopovým skóre pod normou není statisticky významně vyšší než podíl v běžné populaci (p=0,335).



*** Otázka 9 ***.
*Zadání: Kolikrát je šance na výskyt sebevraždy vyšší u mužů trpících schizofrenií (první epizoda a chronici dohromady) než u žen 
trpících schizofrenií (první epizoda a chronici dohromady)?.

fre pohlavi.
*Z frekvenční tabulky vidíme, že kategorie "ženy" je před kategorií "muži".
*Chceme srovnávat muže vs. ženy, musíme tedy vytvořit novou kategoriální proměnnou, kde budou "muži" před "ženami".
*Uděláme to např. tak, že hodnotu 0 (pro ženy) nahradíme za 2.
RECODE pohlavi (0=2) (ELSE=Copy) INTO pohlavi2.
EXECUTE.
val lab pohlavi2
1 'muži'
2 'ženy'.

*Kontrola, že nyní jsou "muži" před "ženami".
fre pohlavi2.

*Je ještě vhodné obrátit i pořadí kategorií u sebevraždy, abychom měli hodnocenou událost jako 1. kategorii, abychom nemuseli OR 
dopočítávat ručně jako 1/hodnota.
fre sebevrazda.
RECODE sebevrazda (0=2) (ELSE=Copy) INTO sebevrazda2.
EXECUTE.
val lab sebevrazda2
1 'ano'
2 'ne'.
fre sebevrazda2.

*Výpočet OR. 
temp.
sel if skupina=2 or skupina=3.
CROSSTABS
  /TABLES=pohlavi2 BY sebevrazda2
  /FORMAT=AVALUE TABLES
  /STATISTICS=RISK 
  /CELLS=COUNT ROW 
  /COUNT ROUND CELL.
*Sebevraždu spáchalo 16,7% mužů a 3,3% žen. Srovnáváme muže (s vyšším procentem) vs. ženy, budeme tedy očekávat OR > 1.
*OR vyčteme z 1. řádku tabulky - 5,8.
*Interval spolehlivosti 0,635 - 53,012 obsahuje 1 -> OR není statisticky významné.

*Závěr: Šance na výskyt sebevraždy u mužů trpících schizofrenií je 5,8-krát vyšší než u žen trpících schizofrenií,
výsledek však není statisticky významný.

*Poznámka: Pokud bychom chtěli vědět p-hodnotu, můžeme použít online kalkulátor (https://www.medcalc.org/calc/odds_ratio.php),
kde bychom zjistili, že p=0,119.
*Nebo můžeme použít výpočet přes logistickou regresi:.

temp.
sel if skupina=2 or skupina=3.
LOGISTIC REGRESSION VARIABLES sebevrazda
  /METHOD=ENTER pohlavi 
  /PRINT=CI(95)
  /CRITERIA=PIN(0.05) POUT(0.10) ITERATE(20) CUT(0.5).
*V poslední tabulce (Variables in the Equation) vidíme v 1. řádku p-hodnotu (Sig.) a OR (Exp(B)), tedy p=0,119 a OR=5,8.
*Poznámka: U logistické regrese můžeme použít původní proměnné, protože při kódování kategorií jako 0 a 1 se vždy bere hodnota 1 
jako riziková, takže to bude srovnávat muže (1) vs. ženy (0) a správně to i rozpozná událost (tzn. sebevražda = ano (1) ).



*** Otázka 10 ***.
*Zadání: Kolikrát je relativní riziko sebevraždy vyšší u mužů trpících schizofrenií (první epizoda a chronici dohromady) než u žen trpících 
schizofrenií (první epizoda a chronici dohromady)?.

*Použijeme výsledek výpočtu RR a OR z Otázky 9.
*RR vyčteme z 2. řádku (pro sebevrazda2=ano), tzn. RR=5. 
*Interval spolehlivosti 0,621 - 40,285 obsahuje 1 -> RR není statisticky významné.

*Závěr: Riziko výskytu sebevraždy u mužů trpících schizofrenií je 5-krát vyšší než u žen trpících schizofrenií,
výsledek však není statisticky významný.

*Poznámka 1: Datový soubor vznikl tak, že od 1. sběru dat byly subjekty několik let sledovány (tzn. prospektivní studie), RR tedy použít 
můžeme.
*Poznámka 2: Pokud bychom chtěli vědět p-hodnotu, můžeme použít online kalkulátor (http://www.medcalc.org/calc/relative_risk.php),
kde bychom zjistili, že p=0,131.